; Script generated by the Inno Setup Script Wizard.

#define AppName "Ballistic"
#define FileVerStr GetFileVersion(".\Ballistic.exe")
#define AppVerStr Copy(FileVerStr, 1, RPos(".", FileVerStr)-1)
#define AppDataDir "{userappdata}\Ballistic"

[Setup]
AppName={#AppName}
AppVersion={#AppVerStr}
AppVerName={#AppName}
AppPublisherURL=http://ballistic.sourceforge.net/
AppUpdatesURL=http://ballistic.sourceforge.net/
AppSupportURL=http://ballistic.sourceforge.net/
VersionInfoVersion={#FileVerStr}
VersionInfoTextVersion={#AppVerStr}
DefaultDirName={pf}\{#AppName}
DefaultGroupName={#AppName}
DisableProgramGroupPage=auto
Uninstallable=yes
OutputBaseFilename=Ballistic-{#AppVerStr}-setup
OutputDir=.
SetupIconFile=src\Ballistic.ico
Compression=lzma
SolidCompression=yes

[Languages]
Name: "en"; MessagesFile: "compiler:Default.isl"

[Tasks]
Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}"; Flags: unchecked

[Dirs]
; Empty directory. For user created maps (BEdit should choose this as the default save dir)
Name: "{#AppDataDir}\maps"

[Files]
;; Application files
Source: "Ballistic.exe"; DestDir: "{app}"
Source: "BEdit.exe"; DestDir: "{app}"
Source: "QtCore4.dll"; DestDir: "{app}";
Source: "QtGui4.dll"; DestDir: "{app}";
Source: "QtXml4.dll"; DestDir: "{app}";
;Source: "<FMOD>.dll"; DestDir: "{app}";
Source: "readme.txt"; DestDir: "{app}"; Flags: isreadme
Source: "credits.txt"; DestDir: "{app}";
Source: "data\font.xml"; DestDir: "{app}\data"
Source: "data\gamedata.xml"; DestDir: "{app}\data"
Source: "img\*"; DestDir: "{app}\img"; Flags: recursesubdirs createallsubdirs
Source: "mechs\*"; DestDir: "{app}\mechs"; Flags: recursesubdirs createallsubdirs
Source: "maps\*"; DestDir: "{app}\maps"; Flags: recursesubdirs createallsubdirs
Source: "weapons\*"; DestDir: "{app}\weapons"; Flags: recursesubdirs createallsubdirs
Source: "sound\*"; DestDir: "{app}\sound"; Flags: recursesubdirs createallsubdirs
Source: "music\*"; DestDir: "{app}\music"; Flags: recursesubdirs createallsubdirs
Source: "vcredist_x86.exe"; DestDir: {tmp}; Flags: ignoreversion

;; User files
Source: "data\options.cfg"; DestDir: "{#AppDataDir}\data"
Source: "data\settings.cfg"; DestDir: "{#AppDataDir}\data"

[Icons]
Name: "{group}\Ballistic"; Filename: "{app}\Ballistic.exe"
Name: "{group}\{cm:UninstallProgram,Ballistic}"; Filename: "{uninstallexe}"
Name: "{commondesktop}\Ballistic"; Filename: "{app}\Ballistic.exe"; Tasks: desktopicon

[Run]
Filename: {tmp}\vcredist_x86.exe; Parameters: "/q:a"; WorkingDir: {tmp}; Flags: skipifdoesntexist; StatusMsg: "Installing ""Microsoft Visual C++ 2008 Redistributable Package""."